Index: patterns/CMakeLists.txt
===================================================================
--- patterns/CMakeLists.txt	(revision 0)
+++ patterns/CMakeLists.txt	(revision 0)
@@ -0,0 +1,237 @@
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/patterns)
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/engine)
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/sgf)
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/utils)
+
+########### mkpat program ###############
+
+SET(mkpat_SRCS
+    mkpat.c
+    transform.c
+    dfa.c
+    )
+
+ADD_EXECUTABLE(mkpat ${mkpat_SRCS})
+
+TARGET_LINK_LIBRARIES(mkpat utils)
+
+
+########### joseki program ###############
+
+SET(joseki_SRCS
+    joseki.c
+    )
+
+ADD_EXECUTABLE(joseki ${joseki_SRCS})
+
+TARGET_LINK_LIBRARIES(joseki board sgf utils)
+
+
+########### mkeyes program ###############
+
+SET(mkeyes_SRCS
+    mkeyes.c
+    )
+
+ADD_EXECUTABLE(mkeyes ${mkeyes_SRCS})
+
+TARGET_LINK_LIBRARIES(mkeyes utils)
+
+
+########### mkmcpat program ###############
+
+SET(mkmcpat_SRCS
+    mkmcpat.c
+    )
+
+ADD_EXECUTABLE(mkmcpat ${mkmcpat_SRCS})
+
+IF(UNIX)
+    SET(PLATFORM_LIBRARIES m)
+ENDIF(UNIX)
+
+TARGET_LINK_LIBRARIES(mkmcpat engine sgf utils ${PLATFORM_LIBRARIES})
+
+
+########### uncompress_fuseki program ###############
+
+SET(uncompress_fuseki_SRCS
+    uncompress_fuseki.c
+    )
+
+ADD_EXECUTABLE(uncompress_fuseki ${uncompress_fuseki_SRCS})
+
+TARGET_LINK_LIBRARIES(uncompress_fuseki utils board sgf)
+
+
+########### extract_fuseki program ###############
+
+SET(extract_fuseki_SRCS
+    extract_fuseki.c
+    )
+
+ADD_EXECUTABLE(extract_fuseki ${extract_fuseki_SRCS})
+
+TARGET_LINK_LIBRARIES(extract_fuseki engine patterns
+                      engine patterns sgf utils)
+
+
+########### next target ###############
+
+SET(compress_fuseki_SRCS
+    compress_fuseki.c
+    )
+
+ADD_EXECUTABLE(compress_fuseki ${compress_fuseki_SRCS})
+
+TARGET_LINK_LIBRARIES(compress_fuseki)
+
+
+########### Generate files. ##############
+
+GET_TARGET_PROPERTY(JOSEKI_EXE joseki LOCATION)
+GET_TARGET_PROPERTY(MKPAT_EXE mkpat LOCATION)
+GET_TARGET_PROPERTY(MKEYES_EXE mkeyes LOCATION)
+GET_TARGET_PROPERTY(MKMCPAT_EXE mkmcpat LOCATION)
+GET_TARGET_PROPERTY(UNCOMPRESS_FUSEKI_EXE uncompress_fuseki LOCATION)
+
+SET(JOSEKI_INPUTS "")
+SET(JOSEKI_NAMES "")
+SET(GG_BUILT_SOURCES "")
+MACRO(BUILD_JOSEKI NAME PREFIX)
+    ADD_CUSTOM_COMMAND(
+        OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NAME}.db
+        COMMAND ${JOSEKI_EXE} ${PREFIX}
+	        ${CMAKE_CURRENT_SOURCE_DIR}/${NAME}.sgf
+                > ${CMAKE_CURRENT_BINARY_DIR}/${NAME}.db
+        DEPENDS joseki ${CMAKE_CURRENT_SOURCE_DIR}/${NAME}.sgf
+    )
+    SET(JOSEKI_INPUTS ${JOSEKI_INPUTS}
+                      "-i" ${CMAKE_CURRENT_BINARY_DIR}/${NAME}.db)
+    SET(JOSEKI_NAMES ${JOSEKI_NAMES}
+                     ${CMAKE_CURRENT_BINARY_DIR}/${NAME}.db)
+ENDMACRO(BUILD_JOSEKI)
+
+BUILD_JOSEKI(gogo JG)
+BUILD_JOSEKI(hoshi_keima JHK)
+BUILD_JOSEKI(hoshi_other JHO)
+BUILD_JOSEKI(komoku JK)
+BUILD_JOSEKI(sansan JS)
+BUILD_JOSEKI(mokuhazushi JM)
+BUILD_JOSEKI(takamoku JT)
+
+MACRO(RUN_MKPAT OPTIONS1 OPTIONS2 PATNAME DBNAME CNAME)
+    ADD_CUSTOM_COMMAND(
+        OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${CNAME}
+        COMMAND ${MKPAT_EXE} ${OPTIONS1} ${OPTIONS2} ${PATNAME}
+                             -i ${CMAKE_CURRENT_SOURCE_DIR}/${DBNAME}
+                             -o ${CMAKE_CURRENT_BINARY_DIR}/${CNAME}
+        DEPENDS mkpat ${CMAKE_CURRENT_SOURCE_DIR}/${DBNAME}
+        )
+    SET(GG_BUILT_SOURCES ${GG_BUILT_SOURCES} ${CMAKE_CURRENT_BINARY_DIR}/${CNAME})
+ENDMACRO(RUN_MKPAT)
+
+SET(DFAFLAGS -D -m)
+
+MACRO(RUN_MKPAT_DFA OPTIONS PATNAME DTRNAME DBNAME CNAME)
+    ADD_CUSTOM_COMMAND(
+        OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${CNAME}
+        COMMAND ${MKPAT_EXE} ${DFAFLAGS} ${OPTIONS}
+                             -t ${CMAKE_CURRENT_SOURCE_DIR}/${DTRNAME} ${PATNAME}
+                             -i ${CMAKE_CURRENT_SOURCE_DIR}/${DBNAME}
+                             -o ${CMAKE_CURRENT_BINARY_DIR}/${CNAME}
+        DEPENDS mkpat ${CMAKE_CURRENT_SOURCE_DIR}/${DBNAME}
+                      ${CMAKE_CURRENT_SOURCE_DIR}/${DTRNAME}
+        )
+    SET(GG_BUILT_SOURCES ${GG_BUILT_SOURCES} ${CMAKE_CURRENT_BINARY_DIR}/${CNAME})
+ENDMACRO(RUN_MKPAT_DFA)
+
+MACRO(RUN_UNCOMPRESS_FUSEKI BOARDSIZE)
+    ADD_CUSTOM_COMMAND(
+        OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/fuseki${BOARDSIZE}.c
+        COMMAND ${UNCOMPRESS_FUSEKI_EXE} ${BOARDSIZE}
+                             ${CMAKE_CURRENT_SOURCE_DIR}/fuseki${BOARDSIZE}.dbz
+                             c > ${CMAKE_CURRENT_BINARY_DIR}/fuseki${BOARDSIZE}.c
+        DEPENDS uncompress_fuseki
+                ${CMAKE_CURRENT_SOURCE_DIR}/fuseki${BOARDSIZE}.dbz
+        )
+    SET(GG_BUILT_SOURCES ${GG_BUILT_SOURCES}
+                         ${CMAKE_CURRENT_BINARY_DIR}/fuseki${BOARDSIZE}.c)
+ENDMACRO(RUN_UNCOMPRESS_FUSEKI)
+
+# FIXME: It's very ugly that the RUN_MKPAT macro takes two separate
+# option arguments, where one is in most cases eliminated by using "".
+# The problem with just having one option argument is that specifying
+# it as "-c -b" causes the space to be escaped into "-c\ -b". There is
+# probably some trivial workaround for someone who actually knows cmake.
+RUN_MKPAT(-X "" attpat attack.db apatterns.c)
+RUN_MKPAT("" "" defpat defense.db dpatterns.c)
+RUN_MKPAT(-b "" handipat handicap.db handipat.c)
+RUN_MKPAT(-c "" influencepat influence.db influence.c)
+RUN_MKPAT(-c -b barrierspat barriers.db barriers.c)
+RUN_MKPAT(-b "" endpat endgame.db endgame.c)
+RUN_MKPAT(-c "" conn conn.db conn.c)
+RUN_MKPAT(-b "" fusekipat fuseki.db fusekipat.c)
+RUN_MKPAT_DFA(-b aa_attackpat aa_attackpats.dtr aa_attackpats.db aa_attackpat.c)
+RUN_MKPAT_DFA(-b owl_vital_apat owl_vital_apats.dtr owl_vital_apats.db owl_vital_apat.c)
+RUN_MKPAT_DFA(-b owl_attackpat owl_attackpats.dtr owl_attackpats.db owl_attackpat.c)
+RUN_MKPAT_DFA(-b owl_defendpat owl_defendpats.dtr owl_defendpats.db owl_defendpat.c)
+RUN_UNCOMPRESS_FUSEKI(9)
+RUN_UNCOMPRESS_FUSEKI(13)
+RUN_UNCOMPRESS_FUSEKI(19)
+
+ADD_CUSTOM_COMMAND(
+   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/josekidb.c
+   COMMAND ${MKPAT_EXE} -C joseki ${JOSEKI_INPUTS}
+                        -o ${CMAKE_CURRENT_BINARY_DIR}/josekidb.c
+   DEPENDS mkpat ${JOSEKI_NAMES}
+   )
+SET(GG_BUILT_SOURCES ${GG_BUILT_SOURCES}
+                     ${CMAKE_CURRENT_BINARY_DIR}/josekidb.c)
+   
+ADD_CUSTOM_COMMAND(
+   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/patterns.c
+   COMMAND ${MKPAT_EXE} -b pat -i ${CMAKE_CURRENT_SOURCE_DIR}/patterns.db
+                               -i ${CMAKE_CURRENT_SOURCE_DIR}/patterns2.db
+                               -o ${CMAKE_CURRENT_BINARY_DIR}/patterns.c
+   DEPENDS mkpat ${CMAKE_CURRENT_SOURCE_DIR}/patterns.db
+                 ${CMAKE_CURRENT_SOURCE_DIR}/patterns2.db
+   )
+SET(GG_BUILT_SOURCES ${GG_BUILT_SOURCES}
+                     ${CMAKE_CURRENT_BINARY_DIR}/patterns.c)
+
+ADD_CUSTOM_COMMAND(
+   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/eyes.c
+   COMMAND ${MKEYES_EXE} < ${CMAKE_CURRENT_SOURCE_DIR}/eyes.db
+                         > ${CMAKE_CURRENT_BINARY_DIR}/eyes.c
+   DEPENDS mkeyes ${CMAKE_CURRENT_SOURCE_DIR}/eyes.db
+   )
+SET(GG_BUILT_SOURCES ${GG_BUILT_SOURCES} ${CMAKE_CURRENT_BINARY_DIR}/eyes.c)
+
+ADD_CUSTOM_COMMAND(
+   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/mcpat.c
+   COMMAND ${MKMCPAT_EXE} ${CMAKE_CURRENT_SOURCE_DIR}/mc_montegnu_classic.db
+                          ${CMAKE_CURRENT_SOURCE_DIR}/mc_mogo_classic.db
+                          ${CMAKE_CURRENT_SOURCE_DIR}/mc_uniform.db
+			  > ${CMAKE_CURRENT_BINARY_DIR}/mcpat.c
+   DEPENDS mkmcpat ${CMAKE_CURRENT_SOURCE_DIR}/mkmcpat.c
+                   ${CMAKE_CURRENT_SOURCE_DIR}/mc_montegnu_classic.db
+                   ${CMAKE_CURRENT_SOURCE_DIR}/mc_mogo_classic.db
+                   ${CMAKE_CURRENT_SOURCE_DIR}/mc_uniform.db
+   )
+
+SET(GG_BUILT_SOURCES ${GG_BUILT_SOURCES}
+                     ${CMAKE_CURRENT_BINARY_DIR}/mcpat.c)
+
+
+
+########### patterns library ###############
+
+SET(patterns_STAT_SRCS
+    connections.c
+    helpers.c
+    transform.c
+    ${GG_BUILT_SOURCES}
+    )
+
+ADD_LIBRARY(patterns STATIC ${patterns_STAT_SRCS})
Index: CMakeLists.txt
===================================================================
--- CMakeLists.txt	(revision 0)
+++ CMakeLists.txt	(revision 0)
@@ -0,0 +1,46 @@
+PROJECT(GNUGo)
+
+INCLUDE(CheckIncludeFiles)
+CHECK_INCLUDE_FILES(sys/times.h HAVE_SYS_TIMES_H)
+CHECK_INCLUDE_FILES(sys/time.h HAVE_SYS_TIME_H)
+CHECK_INCLUDE_FILES("sys/time.h;time.h" TIME_WITH_SYS_TIME)
+CHECK_INCLUDE_FILES(unistd.h HAVE_UNISTD_H)
+CHECK_INCLUDE_FILES(curses.h HAVE_CURSES_H)
+CHECK_INCLUDE_FILES(glib.h HAVE_GLIB_H)
+CHECK_INCLUDE_FILES(ncurses/curses.h HAVE_NCURSES_CURSES_H)
+CHECK_INCLUDE_FILES(ncurses/term.h HAVE_NCURSES_TERM_H)
+CHECK_INCLUDE_FILES(sys/types.h HAVE_SYS_TYPES_H)
+CHECK_INCLUDE_FILES(term.h HAVE_TERM_H)
+CHECK_INCLUDE_FILES(crtdbg.h HAVE_CRTDBG_H)
+CHECK_INCLUDE_FILES("winsock.h;io.h" HAVE_WINSOCK_IO_H)
+
+INCLUDE(CheckTypeSize)
+CHECK_TYPE_SIZE(long SIZEOF_LONG)
+
+INCLUDE(CheckFunctionExists)
+CHECK_FUNCTION_EXISTS(times HAVE_TIMES)
+CHECK_FUNCTION_EXISTS(usleep HAVE_USLEEP)
+CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
+CHECK_FUNCTION_EXISTS(vsnprintf HAVE_VSNPRINTF)
+CHECK_FUNCTION_EXISTS(_vsnprintf HAVE__VSNPRINTF)
+# FIXME: Probably necessary to add the glib library for this test to pass.
+CHECK_FUNCTION_EXISTS(g_vsnprintf HAVE_G_VSNPRINTF)
+
+SET(PRAGMAS "")
+IF(WIN32)
+    SET(PRAGMAS "#pragma warning(disable: 4244 4305)")
+ENDIF(WIN32)
+
+CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake
+               ${CMAKE_CURRENT_BINARY_DIR}/config.h)
+
+# Make sure all files know about and can find config.h
+ADD_DEFINITIONS(-DHAVE_CONFIG_H)
+INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR})
+
+# Recurse into subdirectories.
+ADD_SUBDIRECTORY(utils) 
+ADD_SUBDIRECTORY(sgf) 
+ADD_SUBDIRECTORY(engine) 
+ADD_SUBDIRECTORY(patterns) 
+ADD_SUBDIRECTORY(interface) 
Index: sgf/CMakeLists.txt
===================================================================
--- sgf/CMakeLists.txt	(revision 0)
+++ sgf/CMakeLists.txt	(revision 0)
@@ -0,0 +1,22 @@
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/utils)
+
+########### sgfgen program ###############
+
+SET(sgfgen_SRCS
+    sgfgen.c
+    )
+
+ADD_EXECUTABLE(sgfgen ${sgfgen_SRCS})
+
+TARGET_LINK_LIBRARIES(sgfgen)
+
+
+########### sgf library ###############
+
+SET(sgf_STAT_SRCS
+    sgf_utils.c
+    sgfnode.c
+    sgftree.c
+    )
+
+ADD_LIBRARY(sgf STATIC ${sgf_STAT_SRCS})
Index: utils/gg_utils.c
===================================================================
--- utils/gg_utils.c	(revision 2414)
+++ utils/gg_utils.c	(working copy)
@@ -224,7 +224,7 @@
   vsnprintf(dest, len, fmt, args);
 #elif HAVE_G_VSNPRINTF
   g_vsnprintf(dest, len, fmt, args);
-#elif HAVE_VISUAL_C
+#elif HAVE__VSNPRINTF_C
   _vsnprintf(dest, len, fmt, args);
 #else
   UNUSED(len);
Index: utils/gg_utils.h
===================================================================
--- utils/gg_utils.h	(revision 2414)
+++ utils/gg_utils.h	(working copy)
@@ -47,7 +47,7 @@
 #include <io.h>
 #endif
 
-#ifdef HAVE_VISUAL_C
+#ifdef HAVE_WINSOCK_IO_H
 #include <winsock.h>
 #include <io.h>
 #endif
Index: utils/CMakeLists.txt
===================================================================
--- utils/CMakeLists.txt	(revision 0)
+++ utils/CMakeLists.txt	(revision 0)
@@ -0,0 +1,9 @@
+SET(utils_STAT_SRCS
+    getopt.c
+    getopt1.c
+    random.c
+    gg_utils.c
+    winsocket.c
+    )
+
+ADD_LIBRARY(utils STATIC ${utils_STAT_SRCS})
Index: interface/gmp.c
===================================================================
--- interface/gmp.c	(revision 2414)
+++ interface/gmp.c	(working copy)
@@ -55,7 +55,7 @@
 #include <io.h>
 #endif
 
-#ifdef HAVE_VISUAL_C
+#ifdef HAVE_WINSOCK_IO_H
 #include <winsock.h>
 #include <io.h>
 #endif
Index: interface/CMakeLists.txt
===================================================================
--- interface/CMakeLists.txt	(revision 0)
+++ interface/CMakeLists.txt	(revision 0)
@@ -0,0 +1,30 @@
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/engine)
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/sgf)
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/utils)
+
+########### gnugo executable ###############
+
+SET(gnugo_SRCS
+    main.c
+    play_ascii.c
+    play_gmp.c
+    play_gtp.c
+    play_solo.c
+    play_test.c
+    gmp.c
+    gtp.c
+    )
+
+ADD_EXECUTABLE(gnugo ${gnugo_SRCS})
+
+IF(WIN32)
+    SET(PLATFORM_LIBRARIES wsock32)
+ENDIF(WIN32)
+
+IF(UNIX)
+    SET(PLATFORM_LIBRARIES m)
+ENDIF(UNIX)
+
+TARGET_LINK_LIBRARIES(gnugo sgf engine sgf utils patterns ${PLATFORM_LIBRARIES})
+
+INSTALL(TARGETS gnugo DESTINATION bin)
Index: engine/gnugo.h
===================================================================
--- engine/gnugo.h	(revision 2414)
+++ engine/gnugo.h	(working copy)
@@ -38,8 +38,8 @@
 #include <config.h>
 #endif
 
-#ifdef HAVE_VISUAL_C
-# include <crtdbg.h>
+#ifdef HAVE_CRTDBG_H
+#include <crtdbg.h>
 #endif
 
 #include "sgftree.h"
Index: engine/CMakeLists.txt
===================================================================
--- engine/CMakeLists.txt	(revision 0)
+++ engine/CMakeLists.txt	(revision 0)
@@ -0,0 +1,62 @@
+INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR})
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/patterns)
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/sgf)
+INCLUDE_DIRECTORIES(${GNUGo_SOURCE_DIR}/utils)
+
+
+########### engine library ###############
+
+SET(engine_STAT_SRCS
+    aftermath.c
+    board.c
+    boardlib.c
+    breakin.c
+    cache.c
+    clock.c
+    combination.c
+    dragon.c
+    endgame.c
+    filllib.c
+    fuseki.c
+    genmove.c
+    globals.c
+    handicap.c
+    hash.c
+    influence.c
+    interface.c
+    matchpat.c
+    montecarlo.c
+    move_reasons.c
+    movelist.c
+    optics.c
+    oracle.c
+    owl.c
+    persistent.c
+    printutils.c
+    readconnect.c
+    reading.c
+    semeai.c
+    sgfdecide.c
+    sgffile.c
+    shapes.c
+    showbord.c
+    surround.c
+    unconditional.c
+    utils.c
+    value_moves.c
+    worm.c
+    )
+
+ADD_LIBRARY(engine STATIC ${engine_STAT_SRCS})
+
+
+########### board library ###############
+
+SET(board_STAT_SRCS
+    board.c
+    boardlib.c
+    hash.c
+    printutils.c
+    )
+
+ADD_LIBRARY(board STATIC ${board_STAT_SRCS})
Index: config.h.cmake
===================================================================
--- config.h.cmake	(revision 0)
+++ config.h.cmake	(revision 0)
@@ -0,0 +1,131 @@
+/* Ruleset. Default Japanese */
+#define CHINESE_RULES 0
+
+/* Allow resignation. Default enabled */
+#define RESIGNATION_ALLOWED 1
+
+/* Default level (strength). Up to 10 supported */
+#define DEFAULT_LEVEL 10
+
+/* Center oriented influence. Disabled by default. */
+#define COSMIC_GNUGO 0
+
+/* Owl Node Limit. 1000 default. */
+#define OWL_NODE_LIMIT 1000
+
+/* Semeai Variations. 500 default */
+#define SEMEAI_NODE_LIMIT 500
+
+/* Default hash table size in megabytes */
+#define DEFAULT_MEMORY -1
+
+/* Compile support for GTP communication over TCP/IP channel. */
+#undef ENABLE_SOCKET_SUPPORT
+
+/* GAIN/LOSS codes. Disabled by default. */
+#define EXPERIMENTAL_OWL_EXT 0
+
+/* Large Scale Captures. Disabled by default. */
+#define LARGE_SCALE 0
+
+/* Oracle. Default not enabled. */
+#define ORACLE 0
+
+/* Owl Threats. 0 standard. */
+#define OWL_THREATS 0
+
+/* Break-in module. Enabled by default. */
+#define USE_BREAK_IN 1
+
+/* Connection module. Default experimental. */
+#define EXPERIMENTAL_CONNECTIONS 1
+
+/* Connection module. Default standard. */
+#define ALTERNATE_CONNECTIONS 1
+
+/* Define as 1 to use the grid optimisation, or 2 to run it in self-test mode
+   */
+#define GRID_OPT 1
+
+/* Define to use ansi escape sequences for color debugging */
+#undef ANSI_COLOR
+
+/* Define to 1 if you have the <curses.h> header file. */
+#cmakedefine HAVE_CURSES_H 1
+
+/* Define to 1 if you have the `gettimeofday' function. */
+#cmakedefine HAVE_GETTIMEOFDAY 1
+
+/* Define to 1 if you have the <glib.h> header file. */
+#cmakedefine HAVE_GLIB_H 1
+
+/* Define to 1 if you have the `g_vsnprintf' function. */
+#cmakedefine HAVE_G_VSNPRINTF 1
+
+/* Define to 1 if you have the <ncurses/curses.h> header file. */
+#cmakedefine HAVE_NCURSES_CURSES_H 1
+
+/* Define to 1 if you have the <ncurses/term.h> header file. */
+#cmakedefine HAVE_NCURSES_TERM_H 1
+
+/* Define to 1 if you have the <sys/times.h> header file. */
+#cmakedefine HAVE_SYS_TIMES_H 1
+
+/* Define to 1 if you have the <sys/time.h> header file. */
+#cmakedefine HAVE_SYS_TIME_H 1
+
+/* Define to 1 if you have the <sys/types.h> header file. */
+#cmakedefine HAVE_SYS_TYPES_H 1
+
+/* Define to 1 if you have the <term.h> header file. */
+#cmakedefine HAVE_TERM_H 1
+
+/* Define to 1 if you have the <crtdbg.h> header file. */
+#cmakedefine HAVE_CRTDBG_H 1
+
+/* Define to 1 if you have the <winsock.h> and <io.h> header files. */
+#cmakedefine HAVE_WINSOCK_IO_H 1
+
+/* Define to 1 if you have the `times' function. */
+#cmakedefine HAVE_TIMES 1
+
+/* Define if your compiler supports transparent unions */
+#undef HAVE_TRANSPARENT_UNIONS
+
+/* Define to 1 if you have the <unistd.h> header file. */
+#cmakedefine HAVE_UNISTD_H 1
+
+/* Define to 1 if you have the `usleep' function. */
+#cmakedefine HAVE_USLEEP 1
+
+/* Define if #define can take a variable number of arguments */
+#undef HAVE_VARIADIC_DEFINE
+
+/* Define to 1 if you have the `vsnprintf' function. */
+#cmakedefine HAVE_VSNPRINTF 1
+
+/* Define to 1 if you have the `_vsnprintf' function. */
+#cmakedefine HAVE__VSNPRINTF 1
+
+/* Enable GNU Readline support */
+#undef READLINE
+
+/* The size of a `long', as computed by sizeof. */
+#cmakedefine SIZEOF_LONG ${SIZEOF_LONG}
+
+/* Define to 1 if termcap/terminfo is available. */
+#undef TERMINFO
+
+/* Define to 1 if you can safely include both <sys/time.h> and <time.h>. */
+#cmakedefine TIME_WITH_SYS_TIME 1
+
+/* Define special valgrind macros. */
+#undef USE_VALGRIND
+
+/* Version number of package */
+#define VERSION "3.7.11"
+
+/* Define to empty if `const' does not conform to ANSI C. */
+#undef const
+
+${PRAGMAS}